Ytukyg

https://i.snag.gy/iQUyxz.jpg

I'm working on windows application form in VS 2017. The requirement is to draw a bezier curve by using three input numbers like (56, 150, 400).

I'm really confused as how to draw this.

Private Sub DrawCurve_Click(sender As Object, e As EventArgs) Handles DrawCurve.Click

    Try

        'Declared myColor earlier

        Dim color = myColor

        Dim myPen As Pen = New Pen(myColor, 8)

        Dim myGraphics As Graphics = Me.CreateGraphics

        Dim pt1 As Point = New Point(CInt(curvePT1.Text),CInt(curvePT1.Text))

        Dim pt2 As Point = New Point(CInt(curvePT2.Text),CInt(curvePT2.Text))

        Dim pt3 As Point = New Point(CInt(curvePT2.Text),CInt(curvePT2.Text))

        Dim curvedPoints As Point() = {pt1, pt2, pt3}

        'Draw Bezier Curve

        CreateGraphics().Clear(Form.ActiveForm.BackColor)

        myGraphics.DrawBezier(myPen, curvedPoints)

    Catch

        MsgBox("Please enter numerical value!")

    End Try

End Sub

Drawing a spline through three points doesn't produce the same result as drawing a cubic Bezier curve. A spline curve tends to have sharper bends (think of a wire coathanger).

Actually the .Net framework does include quadratic Beziers: the QuadraticBezierSegment in WPF. With suitable references, it wouldn't be hard to make a function to use it in a System.Drawing context.

But it's even easier to draw a quadratic Bezier curve using plain arithmetic. You start by choosing the number of points to plot - 5 points might be enough, or more if you want a smoother result. Here's a function (plus 2 supporting functions) which, given 3 control points and the number of points you want to plot, returns a list of PointFs representing the quadratic Bezier:

        Public Function QuadraticBezier(controlPoint1 As PointF, controlPoint2 As PointF, 

controlPoint3 As PointF, numberOfPoints As Integer) As PointF()



          Dim lst As New List(Of PointF)

          For t As Double = 0 To 1 Step 1 / (numberOfPoints - 1)

             lst.Add(QuadBezierPoint(controlPoint1, controlPoint2, controlPoint3, t))

          Next

          Return lst.ToArray



       End Function



       Private Function QuadBezierPoint(p1 As PointF, p2 As PointF, p3 As PointF, t As Double) 

As PointF



          Dim q1 As PointF = LinearInterpolate(p1, p2, t)

          Dim q2 As PointF = LinearInterpolate(p2, p3, t)

          Return LinearInterpolate(q1, q2, t)



       End Function



       Private Function LinearInterpolate(p1 As PointF, p2 As PointF, t As Double) 

As PointF



          Dim x As Double = p1.X + (p2.X - p1.X) * t

          Dim y As Double = p1.Y + (p2.Y - p1.Y) * t

          Return New PointF(CSng(x), CSng(y))



       End Function

Once you have the points, you can draw the curve however you like, for example using Graphics.DrawCurve or as straight lines. Even with just 5 points, it will look a lot more like a Bezier than drawing through just 3 points.

Afterthought. The simplest possible answer to the original question is just to duplicate one of the available points. For example p2 as here:

    Dim curvedPoints As Point() = {pt1, pt2, pt2, pt3}

    '.... 

    'Draw Bezier Curve

    myGraphics.DrawBezier(myPen, curvedPoints)

The result won't be the same as a quadratic Bezier, because the doubled point 'pulls' harder on the curve. But it will still be a Bezier curve.

BB